The unsteady ebb and flow of your own breath is your only companion as you wait for deliverance, reduced once again to pleading at the feet of your jailers. You'd laugh at the brutal unfairness of it all if your lungs weren't devouring themselves.

A light rapping from without may as well be a cacophony of hammers upon the anvil. Head throbbing, you muster every scrap of energy remaining in your body to drag yourself to your feet and over to the entryway.

It takes all your strength to heave the container open, overbalancing with the effort and narrowly catching yourself from falling. 

"If it isn't Paradigm." Leaning heavily on the door, you drag your gaze upward to see one of your least favourite people, hands tucked nonchalantly in the pockets of their long brown coat. Lullaby. "Our mutual friend Control Group tells me you landed yourself in a spot of bother," they continue, as if you fell a little behind on rent rather than crumbling before their eyes.

You manage to nod. Your eyes dart feverishly to their coat. Do they have a vial in there?

One hand emerges from their pocket. Empty. A twinge of desperation hits you. Lullaby raises the hand and lowers their sunglasses with a single finger, painfully lackadaisical. They peer past you into the container, eyes as dark and empty as ever. "@{livingconditions I love what you've done with the place."|I see you've spruced the place up a little."|Oh, very good, Dime. You do have an eye for décor."}    

The cravings were already unbearable, the pain all-consuming in an entirely literal sense. Their intentional meandering shouldn't be a blip on the radar.

But when you're clinging on by your fingertips, how can you ignore the boot grinding on your hand?
*choice
    #I have enough self-respect not to crawl.
        You watch them as impassively as you can while they flit around, making inane small talk. @{(expressive > 30) Though you try to hold yourself contained, it doesn't take long for your mask to crack. Soon, you're openly staring, wearing your hunger bare and urgent. Lullaby glances your way and meets your eyes. Their mouth curls up, just enough to let you know they noticed.|Somehow, against the odds, you hold yourself contained. Hold to what little dignity you have. Lullaby pauses mid-sentence, looking at you thoughtfully, their expression mildly disappointed and equally mildly impressed.} "Ah, but I'm rambling. I'm sure you're eager for your delivery."
        
    #No I don't.
        *set defiance -1
        What's pride worth if you're dead?
        
        "Please, Lullaby. I—I need this. It's tearing me up, I—"
        
        "Don't blubber, it's undignified. I have your 'Juice', Paradigm." They don't hide their disdain.
        
    #I barely have the strength to stand, but I'm still angry.
        *set defiance +1
        Always with the power games. Rubbing superiority in your face. Even on the brink of death.
        
        "If you're just going to mock me, you can fuck off," you growl, words rasping like broken glass.
        
        Lullaby's mouth twitches. It's almost a smile. "Temper, temper. I have your delivery right here."
        
They pluck a purple vial from their pocket and you can't restrain yourself from snatching it right out of their hand. You're so desperate you forget to remove the cap; you correct that and then start feverishly gulping the vial's life-sustaining contents.

The gnashing teeth devouring you within and without hesitate.

Then recede.
*page_break Relief. Merciful relief.
*set juice 100
*set vials 0
*set dependence + 2
*set juiceless false
*set remotemembrane 1
*set vantagebeating 1
*if ((getspiked = 3) or (surpass_stomach > 1))
    *set injurydesc 9
    *set mc_health 2

*else
    *set mc_health 1
    *set injurydesc 1

You sink against the wall of your container, eyes glazed. There's no surge of electric adrenaline, just a slow and steady lessening of the pain that's consumed you. The Juice courses through your system, refreshing, restoring, repairing.

And despite the agony, despite all you've been through, you can't deny the euphoric high humming through your ravaged body.

As you shudder free of the Juice's intoxicating clutches, you catch Lullaby eyeing you. They're trying to maintain a mask of neutrality, but faint disgust is seeping through.

"You people and your poison," they mutter. Their eyes flick to yours, widening for just an instant as they find you lucid. You don't think they intended you to hear that.

*choice
    #Point out it's not like you have a choice.
        *set coveninfo +1
        *set covenlul true
        
        *if defiance < 4
            *set defiance +1
            
        "It's drink this or die," you say bluntly.
        
        "Why Paradigm, you can't mean to suggest that's the only reason you partake of your dear leader's wondrous creation?"
        
        @{coven_history You freeze up, a deer in the headlights. Disloyalty means punishment. The lash is imminent.|Your words catch in your throat and you stammer out something half excuse and half apology. You didn't mean to imply disloyalty.|Ah. Let a little too much of the real $!{forename} slip out there. You shrug carefully.}
        
        @{coven_history Lullaby sighs. "Stop cringing. Honestly, you're like a whipped dog."|Lullaby smirks. "Adorable. You're so eager to please."|Lullaby says nothing, their eyes lingering on you for several long seconds. You can't tell if you've erred.}
        
        You school your expression and steady your nerves.
        
    #Try to persuade them to elaborate. Carefully.     
        *if knowledge > 40
            *set trust_cg +1
            *set coveninfo +1
            *set covenlul true
            Though your head pounds, there's also something approaching coherent thought. You've never heard them express a negative sentiment before. Or, well, any kind of actual opinion.
            
            You begin, speaking slowly to match your mouth to the pace of your brain. "There are side effects, but poison is going a little far. A lot of powers are double-edged swords. Remember Vault?" That's a pretty deep cut; Vault left the parahuman scene years before you ever got mixed up in it. Still, you don't get to be a masked merc—not with a long career, at least—without keeping your ear to the ground, and you're counting on it here.
            
            "Vault?" They rub their chin, and you can tell you've piqued their interest. "With the stasis ability, correct?"
            
            You nod. "Which turned out to slowly degrade anything he froze." Himself included. You still remember watching Vault's retirement conference on TV. Remember the withered husk of a man the hero had become.
            
            "Hm." Lullaby wavers a hand from side to side. "The leading theory is that Vault was using the power improperly to avoid harming others. Most parahumans don't experience those kinds of ill effects. I can't put myself to sleep, for example." Their lip curls. "Even the best case scenario for the… Juice means permanent addiction. It's no double-edged sword, Dime, it's a tainted chalice."
            
            The criticism is a genuine surprise. You're so used to nobody ever speaking a word against Hypothesis, even obliquely. For a moment you consider persevering for more detail, then decide not to push your luck. Lullaby's all too mercurial for such a risk. Instead you simply nod again.
            
        *else
            That's your intention anyway. Instead you open your mouth and an incoherent jumble of words falls out.
            
            Lullaby regards you a moment, then shakes their head. "Keep trying, Paradigm. You'll produce an actual sentence one of these days."
            
            Chastened, you go silent. More recovery is clearly needed before you start trying to debate anyone.
            
    #Blandly thank them for the delivery: the sooner they're gone, the better.
        *if defiance < 4
            *set defiance +1
        
        "Thank you for this," you say carefully.
        
        "I live to serve." They pause just long enough. "Not you, of course."
        
        You know better than to react.
        
    #Attempt to get some news of the Coven: how screwed am I?
        *set coveninfo +1
        You take a second to psyche yourself up, then just go for it.
        
        "Lullaby, can I ask something?"
        
        "If you like."
        
        "How are things at base?"
        
        *if inform1 < 5
            "Oh, all abuzz, of course. $!{cg} let us know what to expect, and all have been awaiting news of your exploits." They touch a finger to their cheek, miming wiping a tear. "You're all grown up. I could weep." They're stone-faced, and the only thing in their voice is light sardonicism. 
            
            The mockery barely registers. Jibes are pedestrian for you.
            
        *elseif (not (footagedestroy))
            "All abuzz with word of your exploits of course." Their smile is all teeth. "Though it did come as quite a surprise, given you didn't inform us first. Stage fright is only natural, Paradigm, but there's no need to be shy."
            
            Ah. Extremely screwed, then.
            
        *else
            "Mm, calm enough, I suppose."
            
            That's one lie that hasn't come home to roost yet. You can't help feeling that it's only a matter of time.
            
        You hesitate, but you've come this far. "And… what did Hypothesis have to say?"
        
        "About the vial? Good question." Lullaby stops, regarding you with a glint in their eye. You realise they're not going to answer said question. 
        
        That's as far as you dare push. You nod.

Lullaby yawns, checking a non-existent watch. "I had best be going. Take care, Paradigm, and do try to pace yourself better in future."

*if (diming)
    They stride away two steps, pause, then turn back. They're smiling. On another person, you'd call the expression one of mischief. On Lullaby, it's thoroughly capricious "By the by, I hear you've kept $!{mask} for your new career. I'm touched that you're still thinking of us."
    
    And then they're gone for real.
    
*else
    They stride away. You feel deeper in this pit than ever.
    
*return